[FortiGate] ユーザー登録 & SSL VPN の二要素認証メールアドレス登録を Tera Term マクロ化する

<FortiGate のIP アドレス>,<管理者のユーザー名>,<管理者のパスワード>

192.168.0.1,admin,pass

<ユーザー名>,<パスワード>,<二要素認証用メールアドレス>
<ユーザー名>,<パスワード>,<二要素認証用メールアドレス>
<ユーザー名>,<パスワード>,<二要素認証用メールアドレス>
<ユーザー名>,<パスワード>,<二要素認証用メールアドレス>
<ユーザー名>,<パスワード>,<二要素認証用メールアドレス>
...

user1,pass1,user1@sample.com
user2,pass2,user2@sample.com
user3,pass3,user3@sample.com
...

; csv ファイル読み込み用
separator = ','

;--------------- SSH 接続 ---------------

; FortiGate 接続情報読み込み
authenticationfile = 'authentication.csv'
fileopen authentication authenticationfile 0 0

; SSH 接続コマンドを格納する変数
COMMAND_SSH = ''

; SSH 接続コマンドを作成する

while 1

  ; FortiGate 接続情報ファイルから1行を読み込む
  filereadln authentication buf

  ; filereadln で最後の行になると result に 1 が格納される。それ以外は 0 が格納される。
  if result then
    break
  endif

  ; buf を 区切り文字 separator で区切る。区切られた部分文字列を取り出して、システム変数 groupmatchstr1 ～ groupmatchstr3 に返す。
  strsplit buf separator
  ssh_ip = groupmatchstr1
  ssh_user = groupmatchstr2
  ssh_passwd = groupmatchstr3

  ; COMMAND_SSH に接続コマンドを格納
  sprintf2 COMMAND_SSH '%s /ssh /auth=password /user=%s /passwd=%s' ssh_ip ssh_user ssh_passwd

endwhile

; authentication をクローズする
fileclose authentication

; SSH 接続開始
connect COMMAND_SSH

; ログ採取開始。任意のフォルダを指定してください。以下では C ドライブ直下にログを残しています。
logopen 'C:\registration.log' 0 0

;---------------------------------------


;-------------- ユーザー登録 --------------

; ユーザー情報読み込み
userfile = 'user.csv'
fileopen users userfile 0 0

while 1

  ; ユーザー情報ファイルから1行を読み込む
  filereadln users buf

  ; filereadln で最後の行になると result に 1 が格納される。それ以外は 0 が格納される。
  if result then
    break
  endif

  ; buf を 区切り文字 separator で区切る。区切られた部分文字列を取り出して、システム変数 groupmatchstr1 ～ groupmatchstr3 に返す。
  strsplit buf separator
  name = groupmatchstr1
  passwd = groupmatchstr2
  mail = groupmatchstr3

  ; 送信するコマンドの作成
  sprintf2 COMMAND_USER 'edit %s' name
  sprintf2 COMMAND_PASS 'set passwd %s' passwd
  sprintf2 COMMAND_MAIL 'set email-to %s' mail

  ; ローカルユーザーの構成を開始
  wait '#'
  sendln 'config user local'
  
  ; ユーザーが登録されていなければ新規作成。登録されていれば該当するユーザーを編集。
  wait '#'
  sendln COMMAND_USER

  ; パスワードを設定
  wait '#'
  sendln COMMAND_PASS

  ; mail にアドレスが入力されていなければ、result に 0 が入る
  strcompare mail ''

  ; mail にアドレスが入力されていればメールアドレスを登録する
  if result != 0 then

    wait '#'
    sendln 'set two-factor email'

    wait '#'
    sendln COMMAND_MAIL

  endif

  ; 設定を終了
  wait '#'
  sendln 'end'

  ; コマンド初期化
  COMMAND_MAIL = ''
  COMMAND_PASS = ''
  COMMAND_USER = ''

endwhile

; users をクローズする
fileclose users

;---------------------------------------

; ログ取得終了
wait '#'
logclose

; ログアウト
sendln 'exit'

<ホスト名> # config user local

<ホスト名> (local) # edit <ユーザー名>
new entry '<ユーザー名>' added

<ホスト名> (<ユーザー名>) # set passwd <パスワード>

<ホスト名> (<ユーザー名>) # end

<ホスト名> # config user local

<ホスト名> (local) # edit <ユーザー名>
new entry '<ユーザー名>' added

<ホスト名> (<ユーザー名>) # set passwd <パスワード>

<ホスト名> (<ユーザー名>) # set two-factor email

<ホスト名> (<ユーザー名>) # set email-to user@sample.com

<ホスト名> (<ユーザー名>) # end

...